# Contributor: <anrxc.sysphere.org>

pkgname=xf86-video-intel-git
pkgver=20090525
pkgrel=2
pkgdesc="X.org Intel i810/i830/i915/945G/G965+ video drivers"
arch=(i686 x86_64)
url="http://cgit.freedesktop.org/xorg/driver/xf86-video-intel/"
depends=('intel-dri>=7.3' 'libpciaccess>=0.10.5' 'libdrm>=2.4.5' 'libxvmc')
makedepends=('git' 'xorg-util-macros>=1.1.3' 'pkgconfig' 'xorg-server>=1.6.0' 'xf86driproto>=2.0.4' 'glproto>=1.4.9' 'mesa>=7.3')
provides=('xf86-video-intel')
conflicts=('xorg-server<1.6.0' 'xf86-video-i810' 'xf86-video-intel')
replaces=('xf86-video-i810')
options=('!libtool' 'force')
groups=('xorg-video-drivers')
source=()
md5sums=()

_gitroot="git://anongit.freedesktop.org/git/xorg/driver/xf86-video-intel"
_gitname="xf86-video-intel"

build() {
 cd $srcdir

 msg "Connecting to GIT server..."
 if [[ -d $_gitname ]] ; then
   (cd $_gitname && git pull origin)
 else
   git clone $_gitroot $_gitname
 fi
 msg "GIT checkout done or server timeout"
 msg "Starting make..."

 rm -rf $_gitname-build
 cp -r $_gitname $_gitname-build
 cd $_gitname-build

 ./autogen.sh --prefix=/usr --enable-dri || return 1
 make || return 1
 make DESTDIR=$pkgdir install || return 1
}